include_guard()

if (NOT BOARD)
  message(FATAL_ERROR "BOARD not specified")
endif ()

set(SDK_DIR ${TOP}/hw/mcu/nxp/mcux-sdk)
set(CMSIS_DIR ${TOP}/lib/CMSIS_5)

# include board specific
include(${CMAKE_CURRENT_LIST_DIR}/boards/${BOARD}/board.cmake)

# toolchain set up
set(CMAKE_SYSTEM_PROCESSOR cortex-m4 CACHE INTERNAL "System Processor")
set(CMAKE_TOOLCHAIN_FILE ${TOP}/examples/build_system/cmake/toolchain/arm_${TOOLCHAIN}.cmake)

set(FAMILY_MCUS KINETIS_K CACHE INTERNAL "")


#------------------------------------
# BOARD_TARGET
#------------------------------------
# only need to be built ONCE for all examples
function(add_board_target BOARD_TARGET)
  if (NOT TARGET ${BOARD_TARGET})
    add_library(${BOARD_TARGET} STATIC
      # driver
      ${SDK_DIR}/drivers/gpio/fsl_gpio.c
      ${SDK_DIR}/drivers/uart/fsl_uart.c
      ${SDK_DIR}/devices/${MCU_VARIANT}/drivers/fsl_clock.c
      ${SDK_DIR}/devices/${MCU_VARIANT}/system_${MCU_VARIANT}.c
      )
    target_compile_definitions(${BOARD_TARGET} PUBLIC
      )
    target_include_directories(${BOARD_TARGET} PUBLIC
      ${CMSIS_DIR}/CMSIS/Core/Include
      ${SDK_DIR}/devices/${MCU_VARIANT}
      ${SDK_DIR}/devices/${MCU_VARIANT}/drivers
      ${SDK_DIR}/drivers/common
      ${SDK_DIR}/drivers/gpio
      ${SDK_DIR}/drivers/port
      ${SDK_DIR}/drivers/smc
      ${SDK_DIR}/drivers/sysmpu
      ${SDK_DIR}/drivers/uart
      )

    update_board(${BOARD_TARGET})

    # LD_FILE and STARTUP_FILE can be defined in board.cmake
    set(STARTUP_FILE_GNU ${SDK_DIR}/devices/${MCU_VARIANT}/gcc/startup_${MCU_VARIANT}.S)

    target_sources(${BOARD_TARGET} PUBLIC
      ${STARTUP_FILE_${CMAKE_C_COMPILER_ID}}
      )

    if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
      target_link_options(${BOARD_TARGET} PUBLIC
        "LINKER:--script=${LD_FILE_GNU}"
        # nanolib
        --specs=nosys.specs --specs=nano.specs
        )
    elseif (CMAKE_C_COMPILER_ID STREQUAL "IAR")
      target_link_options(${BOARD_TARGET} PUBLIC
        "LINKER:--config=${LD_FILE_IAR}"
        )
    endif ()
  endif ()
endfunction()


#------------------------------------
# Functions
#------------------------------------
function(family_configure_example TARGET RTOS)
  family_configure_common(${TARGET} ${RTOS})

  # Board target
  add_board_target(board_${BOARD})

  #---------- Port Specific ----------
  # These files are built for each example since it depends on example's tusb_config.h
  target_sources(${TARGET} PUBLIC
    # BSP
    ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/family.c
    ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/../board.c
    )
  target_include_directories(${TARGET} PUBLIC
    # family, hw, board
    ${CMAKE_CURRENT_FUNCTION_LIST_DIR}
    ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/../../
    ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/boards/${BOARD}
    )

  # Add TinyUSB target and port source
  family_add_tinyusb(${TARGET} OPT_MCU_KINETIS_K ${RTOS})
  target_sources(${TARGET}-tinyusb PUBLIC
    ${TOP}/src/portable/chipidea/ci_fs/dcd_ci_fs.c
    ${TOP}/src/portable/nxp/khci/hcd_khci.c
    )
  target_link_libraries(${TARGET}-tinyusb PUBLIC board_${BOARD})

  # Link dependencies
  target_link_libraries(${TARGET} PUBLIC board_${BOARD} ${TARGET}-tinyusb)

  # Flashing
  family_flash_jlink(${TARGET})

  if (DEFINED TEENSY_MCU)
    family_add_bin_hex(${TARGET})
    family_flash_teensy(${TARGET})
  endif ()
endfunction()